CMake projekt

CMakeLists.txt

+# Lab03 project
+#
+# Originally created: 2023-03-06.
+#
+# CMakeLists.txt --
+#   Elsődleges CMake file a lab_03 projekt fordításához.
+#   Fontos!
+#     Ez a fájl egy összesített script a két alprojekt kezeléséhez.
+#     Figyeljünk, mit próbálunk fordítani/futtatni!
+#     Például, CLion-ban a futtatás gomb mellett megfelelő program van
+#     kiválasztva; VS-ben pedig megfelelő projektet probálunk elindítani.
+#   Használat:
+#       - parancssor: cmake -B _build -S . && cmake --build _build
+#       - CLion/Visual Studio: Megnyitni a mappát projektként
+#       - HSZK Visual Studio: A meglévő .vcxproj fájlokat érdemes használni
+cmake_minimum_required(VERSION 3.18) # Debian Bullseye
+
+project(cpp_lab_03
+        HOMEPAGE_URL "https://git.ik.bme.hu/Prog2/labor_peldak/lab_02"
+        VERSION 1.0.0
+        LANGUAGES C CXX)
+
+include(CheckCXXCompilerFlag)
+
+add_executable(komplex
+               komplex/elkeszult.h
+               komplex/gtest_lite.h
+               komplex/komplex.cpp
+               komplex/komplex.h
+               komplex/komplex_teszt.cpp)
+
+add_executable(teglalap
+               teglalap/teglalap.cpp)
+
+target_compile_features(komplex PRIVATE cxx_std_98)
+target_compile_features(teglalap PRIVATE cxx_std_98)
+
+set_target_properties(komplex PROPERTIES CXX_EXTENSIONS OFF)
+set_target_properties(teglalap PROPERTIES CXX_EXTENSIONS OFF)
+
+target_compile_options(komplex PRIVATE
+                       $<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>:-Werror>
+                       $<$<CXX_COMPILER_ID:MSVC>:/WX>)
+target_compile_options(teglalap PRIVATE
+                       $<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>:-Werror>
+                       $<$<CXX_COMPILER_ID:MSVC>:/WX>)
+
+
+## CheckWarningFlag(OptionName CacheName) --
+#     Ellenőrzi, hogy az használt fordító érti-e a kapott parancssori kapcsolót.
+function(check_warning_flag OptionName CacheName)
+    if (OptionName MATCHES [[^/]])
+        set(WarningPrefix "")
+    else ()
+        set(WarningPrefix "-W")
+    endif ()
+    check_cxx_compiler_flag("${WarningPrefix}${OptionName}" "HasWarning_${CacheName}")
+    set("HAS_WARNING_${CacheName}" ${HasWarning_${CacheName}} PARENT_SCOPE)
+endfunction()
+
+## generate_warnings(&Target) --
+#     Beállít hibakapcsolókat a kapott target-en.
+function(generate_warnings _Target)
+    set(gw_known_warnings
+        # GCC/Clang
+        extra pedantic error=vla error=non-virtual-dtor
+        parentheses logical-op reorder no-c++98-compat
+        no-reserved-macro-identifier no-unused-macros no-float-equal
+        no-zero-as-null-pointer-constant no-global-constructors
+        no-exit-time-destructors no-unsafe-buffer-usage
+        no-missing-prototypes # kiír nincs előre deklarálva
+        no-deprecated-copy-with-user-provided-dtor # Integer dtor miatt már nincs copy ctora
+        no-c++98-compat-pedantic # variadic macro
+        no-reserved-identifier # _Is_...
+        no-old-style-cast      # gtest_lite
+        no-shadow-field-in-constructor # gtest_lite
+        no-shorten-64-to-32    # gtest_lite
+        # MSVC
+        # conditional expression is constant (nem szereti az ELKESZULT) markot
+        /wd4127
+        # 'function': member function does not override any base class virtual member function
+        /we4263 
+        # 'class': class has virtual functions, but destructor is not virtual
+        /we4265 
+        # 'identifier': illegal qualified name in member declaration
+        /we4596 
+        # 'symbol': exception specification does not match previous declaration
+        /we4986 
+        4
+        /permissive-
+        /diagnostics:caret)
+    # MSVC /Wall == clang -Weverything, arra nincs szükségünk
+    set(gw_found_warnings $<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>:-Wall>)
+
+    foreach (warn IN LISTS gw_known_warnings)
+        string(MAKE_C_IDENTIFIER "${warn}" CacheName)
+        check_warning_flag("${warn}" ${CacheName})
+        if (HAS_WARNING_${CacheName})
+            if (warn MATCHES [[^/]])
+                set(WarningPrefix "")
+            else ()
+                set(WarningPrefix "-W")
+            endif ()
+            list(APPEND gw_found_warnings "${WarningPrefix}${warn}")
+        endif ()
+    endforeach ()
+
+    target_compile_options("${_Target}" PUBLIC ${gw_found_warnings})
+endfunction()
+
+generate_warnings(komplex)
+generate_warnings(teglalap)